;***********************************************************
;FT-220Xdds.asm  rev3.2
;FT-220X用13.1MHz OSC X 3逓倍50MHz VFO
;2012.1.13debug
 
;***********************************************************
	list p=16f84
	INCLUDE		<P16F84A.INC>
	__CONFIG 	_CP_OFF & _WDT_OFF & _PWRTE_ON & _HS_OSC
;********************************************
;  Define Constant or Work
;********************************************
	CBLOCK  0X0D
		
		DAT_CNT			;Dispaly Data Bits Counter
		CNT1				;Timer Counter for CLOCK
		CNT2				;Timer Counter for 10usec
		CNT3				;Timer Counter for 5msec
		CNT4				;Timer Counter for 1sec
		CNT5		           ;Timer Counter for 100usec
		TEMP				;Tempolary Save Area
		KEY				     ;KEY DATA SAVE


		EN_T0				;R_ENCODER T0時の状態
		EN_T1				;R_ENCODER T1時の状態
		SW_T0				;SW T0時の状態
		SW_T1
		F_STEP				;F_STEP 10Hz/100Hz
		
		FREQ_FLG			;FREQ CHANG FLG
		ONOFF_FLG			;VFO ONOFF FLAG	

		SWSET_FLG			;SW SET FLAG	
		PWRON_FLG			;power on時に1回だけセット
		TXMODE_FLG	
		RITMODE_FLG	
		TXON_FLG			;TX ON
		A_LO				;FREQ DATA A_LO TO A_TOP
		A_MD		
		A_HI
		A_TOP		
		B_LO				;FREQ DATA B_LO TO B_TOP		
		B_MD		
		B_HI
		B_TOP
		C_LO				;FREQ DATA C_LO TO C_TOP
		C_MD
		C_HI
		C_TOP
		CTEMP
		D_LO				;FREQ DATA D_LO TO D_TOP
		D_MD
		D_HI
		D_TOP
		FSTEP_LO
		FSTEP_MD
		FSTEP_HI
		FTX_LO			;RIT modeTX Freq
		FTX_MD
		FTX_HI	
		FTX_TOP			;1/13 debug
		FRX_LO			;RIT Mode RX Freq
		FRX_MD
		FRX_HI			
		STEP_LOW_BYTE		;
		DIGIT12				;Hz,10Hz桁
		DIGIT34 			;100Hz,1kHz桁
		DIGIT56				;10kHz,100kHz桁
		DIGIT78 			;1MHz,10MHz桁
		WORK1
		TEMP1
		LP_CNT				;main loop counter
		SHIFT
		E_ADRS
		VFOSW_T0
		VFOSW_T1
		MODESW_T0
		MODESW_T1	
		TXONSW_T0
		TXONSW_T1
		E_DATA
		DATA_SAVE
	ENDC

;********************************
; Main Program
;********************************
		
		ORG		0         
		
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; Initialaization		
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++



		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		call			TIME5M
		CALL		PORTA_SET	;PORT INITIALIZATION
		CALL		PORTB_SET
		CALL		FLG_INI	    	   ;All FLG INI set
		CALL		DDS_INI		;WAKE-UP DDS(LET OUTPUT ON)
		CALL 		FREQ_INI	     ;SET INIT FREQ
		CALL		SEND_DAT	     ;DATA SEND
		call			SW_INI			;vfo_sw & mode_sw initilize
		call		    LPCNT_INT	     ;Loop Counter=0x13
		CALL		REG_MOV1	    ;C_REG TO B_REGへ移動
		CALL		SEND_DAT  	;DATA SEND
		CALL		DAT_CAL		;DATA X 3 + 10.7MHz
		CALL		DATCNV		;BINARY TO BCD
		CALL		REG_MOV2	    ;B_REG TO C_REGへ移動
		CALL		LED_DISP   	;LED DISPLAY
  

;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;Main Routine		
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
MAIN
		CALL		PORTB_SET
;		CALL		LP_CHK		;Loop Count Check if LP=0 then goto EN_SCAN
		CALL		VFO_SW		;VFO SW SET取り込み
		CALL		MODE_SW		;MODE SW SET取り込み
		CALL		EN_SCAN		;R_ENCODER UP/DWN 検出

		CALL		TXON_PWROFF	;TX ON & POWER OFF検出


		CALL		FLG_CHK		;変化したか
		CALL		REG_MOV1	    ;C_REG TO B_REGへ移動
		CALL		SEND_DAT  	;DATA SEND

		CALL		DAT_CAL		;DATA X 3 + 10.7MHz

		CALL		DATCNV		;BINARY TO BCD
		CALL		REG_MOV2	    ;B_REG TO C_REGへ移動

		CALL		LED_DISP   	;LED DISPLAY

		GOTO		MAIN
;********** PORT A & B Initialize****************************
;         RA0,1  Input    RA2-4 Output
;         RB0-6 Input    RB7    Output
;*********************************************************

PORTA_SET
		CLRF		PORTA 	          
		CLRF		PORTB           
		BSF	     STATUS,RP0		;Select bank1
        	MOVLW   	b'00000011'     	;PortA RA0,RA1入力　他出力
        	MOVWF    TRISA          		;にセット
        	BCF	     STATUS,RP0     		;Select Bank0
		RETURN
PORTB_SET
        	BSF      	STATUS,RP0    	;SELECT Bank1
        	MOVLW   	b'01111111'      	;PortB RB0-6 INPUT, 
        	MOVWF   	TRISB          	     ;SET PORT B
	    	BCF	     	STATUS,RP0	  	;Select Bank0
		RETURN  
      	
;********** Flag Clear & Initilize*************************************
FLG_INI
		clrf				SWSET_FLG
		clrf				PWRON_FLG
		clrf				RITMODE_FLG
		clrf				TXON_FLG
		RETURN

;******	DDS INITIALIZE		COMMAND=1***********************

DDS_INI
		CALL 		TIME5M		;WAIT 5mS
		CALL		TIME5M		;WAIT 5mS	
		CALL 		TIME5M		;WAIT 5mS
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)

				;ADDRESS SET
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1

				;COMMAND=1:SET DDS OUTPUT=1
		CALL		BIT1	
		CALL		BIT0	
		CALL		BIT0	
		CALL		BIT0
	
				;8x3=24BITS FREQ.DATA(DUMMY=00H)
		MOVLW		00H
		CALL		TX_BYTE		
		MOVLW		00H
		CALL		TX_BYTE		
		MOVLW		00H
		CALL		TX_BYTE
	
				;2BITS DATA=00H
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0	;STROBE=0

		RETURN

;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;		EEPROM DATA CHCK  
;		if EEPROM Data  38.3<Data<43.3MHz Data Good 
;		else Initial freq=FREQ_INI1 or FREQ_INI2	
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
FREQ_INI
		clrf			B_TOP
		clrf			C_TOP
		MOVLW   	0x00
		MOVWF	E_ADRS		;EEADRへW REG経由で書き込み
		CALL		RD_EEPROM
		MOVWF	B_HI		;EEPROMデータをB_HIへ
		movwf		C_HI

		MOVLW	0xC2		;49-10.7MHz/3=12.766MHz= C2CDCB
		SUBWF		B_HI,W	     	;0xC2<B_HIをCHK
		BTFSS		STATUS	,C	;IF 0xC2<B_HI THEN C=1
		GOTO		FREQ_INI2
		
		MOVLW	0xDC		;54-10.7/3=14.433MHz=DC3C35
		SUBWF		B_HI,W	     	;B_HI<0xDCをCHK
		BTFSC		STATUS,C	    ;IF B_HI<0xDC THEN C=0
		GOTO		FREQ_INI1
				
		INCF		E_ADRS	,F	;EEPROM ADRS+1
		CALL		RD_EEPROM
		MOVWF	B_MD	     	;EEPROMデータをB_MDへ
		movwf		C_MD
		INCF		E_ADRS	,F	;EEPROM ADRS+1
		CALL		RD_EEPROM
		MOVWF	B_LO		;EEPROMデータをB_LOへ
		movwf		C_LO
		RETURN

RD_EEPROM
	   	 BCF          STATUS, RP0     ; レジスタバンク０を選択
         	MOVF	    	E_ADRS,W       	;データ−エリアアドレス指定
		MOVWF	EEADR
         	 BSF     	STATUS, RP0     ; レジスタバンク１を選択
         	 BSF     	EECON1, RD      ; EEPROM データを読みとる
         	BCF    		STATUS, RP0     ; レジスタバンク０を選択
          	MOVF   	 EEDATA, W       ; EEPROM データ → W レジスタ
		RETURN
		
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++		
;SET Initial Frequency CH1=50,550 CH2=51.000MHz
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
	
FREQ_INI1
		MOVLW		0x00		;
		MOVWF		B_TOP		;
		MOVWF		C_TOP
		MOVLW		0xCA  		; (50.549MHz)13,283.200Hz=CAAF80H TO DATA_B
		MOVWF		B_HI		;
		MOVWF		C_HI
		MOVLW		0xAF		;
		MOVWF		B_MD		;
		MOVWF		C_MD
		MOVLW		0x80		;
		MOVWF		B_LO		;
		MOVWF		C_LO		
		RETURN

FREQ_INI2
		MOVLW		0x00		;
		MOVWF		B_TOP		;
		MOVWF		C_TOP
		MOVLW		0xCC  		; (50.999MHz)13,433,200Hz=CCF970H TO DATA_B
		MOVWF		B_HI		;
		MOVWF		C_HI
		MOVLW		0xF9		;
		MOVWF		B_MD		;
		MOVWF		C_MD
		MOVLW		0x70		;
		MOVWF		B_LO		;
		MOVWF		C_LO
		RETURN

;*********VFO SW設定の検出************************************
;		RB0:  CH1   RB1:  CH2   RB2: RIT   RB3: TX
;*************************************************************
VFO_SW				
		
		bcf			PORTB,7		;bit7=0 setして74LS244選択
		NOP
		MOVF		PORTB,W		;PORTBからSW設定取り込み
		andlw		0x7F			;bit0-6を取り出し
		movwf		SW_T1   		;MODE SW状態をSW_T1として保存　 	

		ANDLW		0x0F
		MOVWF	VFOSW_T1 	;VFO SW状態をVFOSW_T1へ保存
		bcf			TXMODE_FLG,0  ;一旦クリアー
		BTFSC		VFOSW_T1,2   	;Bit2=0ならRITへ
		goto		CH1
		call			RITMODE
		return				

		
CH1
		clrf			RITMODE_FLG	;RITでないならFlg クリア
		BTFSC		VFOSW_T1,0	
		goto		CH2
		CALL		FREQ_INI1  	;CH1選択ならFREQ_INI1へ
		RETURN

CH2
		BTFSC		VFOSW_T1,1	;Bit1=0ならFREQ_INI2へ
		return
		CALL		FREQ_INI2
		RETURN


	

;*********RIT MODE*******************************************
;	現在の周波数データ B_LO〜B_HI DATをFTX_LO〜FTX_HIに保存
;*************************************************************
RITMODE
		btfss		RITMODE_FLG,0	;RIT_FLG setされているか
		call			FREQ_MEMO		;現在のFREQをメモリー
		movf		FTX_LO,W
		movwf		B_LO
		movf		FTX_MD,W
		movwf		B_MD
		movf		FTX_HI,W
		movf		B_HI


		return


FREQ_MEMO
		movf		B_LO,W
		MOVWF		FTX_LO
		movf		B_MD,W
		MOVWF		FTX_MD
		movf		B_HI,W
		MOVWF		FTX_HI
		bsf			RITMODE_FLG,0	;Rit mode flg set
		RETURN
		
;*********MODE SW設定の検出***********************************
;          RB4=SSB/CW  RB5=AM  RB6=FM
;	   周波数ステップ設定　SSB/CW=9Hz AM=30Hz FM=99Hz
;**************************************************************

MODE_SW
		movf		SW_T1,W	
		XORWF		SW_T0,W			;SW_T0とSW_T1比較
		BTFSC		STATUS,Z		    ;変化していたらZ=0
		goto		FLG_CLR		    ;変化し無しなら
		movf        SW_T1,W		    ;T1を新たなT0とする
		movwf      SW_T0
		BSF		SWSET_FLG,0
		goto		SSBCW

FLG_CLR
		bcf			SWSET_FLG,0
	
SSBCW
		BTFSC		SW_T0,4		;bit4=0ならSSBCW
		GOTO		AM
		MOVLW	0x03		     	;9/3=3Hz STEP
		MOVWF	FSTEP_LO
		movlw		0x00
		movwf		FSTEP_MD
		movlw		0x00
		movwf		FSTEP_HI
	
AM
		BTFSC		SW_T0,5		;bit5=0ならAM
		GOTO		FM
		MOVLW	0x10		     	;30/3=10Hz STEP
		MOVWF	FSTEP_LO
		MOVLW	0x00
		MOVWF	FSTEP_MD
		movlw		0x00
		movwf		FSTEP_HI
FM
		BTFSC		SW_T0,6		;bit6=0ならFM
		RETURN
		MOVLW	0x21		        ;99/3=33Hz STEP
		MOVWF	FSTEP_LO
		MOVLW	0x00
		MOVWF	FSTEP_MD
		movlw		0x00
		movwf		FSTEP_HI
		RETURN

;*********ロータリ−エンコーダー変化検出**********************
EN_SCAN

		MOVF		PORTA,W	      	;
		MOVWF	EN_T0		     	;T0時の状態をSAVE
EN_SCAN_SUB

		CALL		TIME1M   		  ;1mS WAIT		
		call			TIME1M	
		MOVF		PORTA,W			;もう一度R_ENの状態を見る
		MOVWF		EN_T1			;T1時の状態をSAVE
		XORWF		EN_T0,W			;EN_T0とEN__T1を比較して
		BTFSC		STATUS,Z	     	;変化していたらEN_CHECK
		GOTO		LPCNT_CHK
		GOTO		EN_CHECK

;********周波数変化フラグリセット & Loop Count CHK**********************************
LPCNT_CHK
		BCF 		FREQ_FLG,0		;		
	
		RETURN

;********ロータリーエンコーダー回転方向検出***********************************
EN_CHECK
		BSF		FREQ_FLG,0		;周波数変化あればフラグセット
		RLF		EN_T0			    ;ビットシフト
		MOVLW	03H		     	;下位2ビット取り出し
		ANDWF		EN_T0,F			;ビットマスク
		ANDWF		EN_T1,W
		ADDWF		EN_T0,F			;EN_T0とEN_T1を加算して
		BTFSC		EN_T0,1			;2ビット目が1ならCWへ
		GOTO		EN_CCW			;0ならCCWへ
		GOTO		EN_CW

;*******ロータリーエンコーダー反時計方向回転処理*******************************
		
EN_CCW						
		MOVF		FSTEP_LO,W		;STEP周波数をDへ
		MOVWF	D_LO
		MOVF		FSTEP_MD,W
		MOVWF	D_MD
		MOVLW	0x00
		MOVF		FSTEP_HI,W
		MOVWF	D_HI
		MOVWF	D_TOP
		CALL		T_SUB			;減算処理へ
		RETURN

;*******ロータリーエンコーダー時計方向回転処理***************
EN_CW							
		MOVF		FSTEP_LO,W		;STEP周波数をDへ
		MOVWF	D_LO
		MOVF		FSTEP_MD,W
		MOVWF	D_MD
		MOVLW	0x00
		MOVF		FSTEP_HI,W
		MOVWF	D_HI
		MOVWF	D_TOP
		CALL		T_ADD			    ;加算処理へ
		RETURN

;*********TX ON検出*************************************
;		RA0 : TX ON時　L
;		RA1 : POWER OFF時　L
;*******************************************************
TXON_PWROFF
	
		bsf			STATUS,RP0		;select bank0
		movlw		b'00001111'		;RB0-3 Input
		MOVWF		TRISB
		bcf			STATUS,RP0
		
		MOVLW	b'11110000'		;RB7=1 Set 74LS138 ABC=1
		MOVWF	PORTB
		call			TIME1M

TXCHK_LP
		MOVF		PORTA,W			;PORTA DATAを取り込み
		MOVWF	TXONSW_T1		;取り込んだDATAをT1として		
		BTFSC		TXONSW_T1,1		;RA1 0ならPWR OFF
		GOTO		TXONOFF_CHK	    	;TX ON/OFF CHK
		GOTO		DATA_WRITE		;PWR OFF DATA SAVE


TXONOFF_CHK
		btfss		RITMODE_FLG,0	;RIT MODEならTX ONOFF CHK
		goto		LT_SET
		btfsc		TXONSW_T1,0		;TX ON時Lなら 
		goto		TX_OFF			;
		goto		TX_ON
		goto		TXCHK_LP

TX_ON
		btfsc		TXON_FLG,0		;TX ONしていなければFRX save
		goto		TXCHK_LP
		movf		C_LO,W				;今のFreqをFRX_LO-HIへSave
		movwf		FRX_LO
		movf		C_MD,W
		movwf		FRX_MD
		movf		C_HI,W
		movwf		FRX_HI

		movf		FTX_LO,W
		movwf		B_LO
		movf		FTX_MD,W
		movwf		B_MD
		movf		FTX_HI,W
		movf		B_HI

		bsf			TXON_FLG,0 
		call				RITDAT_SEND
		goto		TXCHK_LP

TX_OFF

		btfss		TXON_FLG,0			;TX ONしていたか?
		goto		LT_SET

		movf		FRX_LO,W				;FRX_LO-HI to B_LO-HIへ	
		movwf		B_LO
		movf		FRX_MD,W
		movwf		B_MD
		movf		FRX_HI,W
		movwf		B_HI
		call			SEND_DAT				;RX Freq send
		clrf			TXON_FLG				

LT_SET
		MOVLW	b'01110000'		;RB7=1 SETMOVLW	b'01110000'　　 	
		MOVWF		PORTB
		return


;*********DATA SAVE at PWR OFF******************
DATA_WRITE

		MOVLW		0x0
		MOVWF		E_ADRS
		MOVF	     	B_HI,W			;B_HI DATAを2000HへSAVE
		MOVWF		E_DATA
		CALL	     	WR_EEPROM
		INCF		E_ADRS,F		;ADRS+1
		MOVF		B_MD,W
		MOVWF		E_DATA
		CALL		WR_EEPROM
		
		INCF		E_ADRS,F
		MOVF		B_LO,W
		MOVWF		E_DATA
		CALL		WR_EEPROM
		goto        PWR_OFF
	;	return

WR_EEPROM						;EEPROM書き込み
		BCF		STATUS,RP0		;SET Page0
		MOVF		E_ADRS,W
		MOVWF		EEADR
		MOVF		E_DATA,W
		MOVWF		EEDATA
		BSF			STATUS,RP0
		BSF			EECON1,WREN
		MOVLW		0x55			;書き込み処理
		MOVWF		EECON2
		movlw			0AAH			;10101010
		movwf			EECON2
		BSF			EECON1,WR

WR_LP
		BTFSC		EECON1,WR
		GOTO		WR_LP 				;debug時のみnopとする
		BCF		STATUS,RP0
		RETURN

;*********FLG_CHK検出****************************
FLG_CHK
	
		btfsc		SWSET_FLG,0		;if swset_flg bit0=1 then return
		return
	
		BTFSS		FREQ_FLG,0		;if freq_flg bit0=1 then return
	    	 GOTO		MAIN
		RETURN
		
;*********C_L,M,HとB_L,M.Hの移動**************************
REG_MOV1
		MOVF		C_LO,W		     	;C_LOの内容をB_LOへ
		MOVWF	B_LO
		MOVF		C_MD,W			;C_MIDの内容をB_MIDへ
		MOVWF	B_MD
		MOVF		C_HI,W		     	;C_HIの内容をB_HIへ
		MOVWF	B_HI		
		RETURN

REG_MOV2
		MOVF		B_LO,W		     	;B_LOの内容をC_LOへ
		MOVWF	C_LO
		MOVF		B_MD,W			;B_MIDの内容をC_MIDへ
		MOVWF	C_MD
		MOVF		B_HI,W		     	;B_HIの内容をC_HIへ
		MOVWF	C_HI		
		RETURN

;***** Date Send to DDS************
SEND_DAT
		CALL		TXD
		RETURN

RITDAT_SEND
		call			RIT_TX				;1/15 debug
		return

;***** vfo_sw & mode_sw 初期化********
SW_INI
		movlw		0x7F				;SW_INI=01111111のダミーをセット
		movwf		SW_T0				;sw_data initialize
		return
			
;***** Loop Counter 初期化 **********
LPCNT_INT
		movlw		0x00
		movwf		LP_CNT
		RETURN	

;***** Loop Count Check *************
LP_CHK
		movf		LP_CNT,W		;Loop CountをW Regへ
		xorlw		0x00
		btfss		STATUS,Z		;LP_CNT=0ならZ=1
		goto 		EN_SCAN		;LP_CNTが0以外ならEN_SCANへ
		return						;LP_CNTが0ならVFo_SWへ
			
;*********バイナリ−を3逓倍(2倍+1倍)にする******************
DAT_CAL				;50MHzVFO仕様　13,267MHz X 3+10.7=50.550MHzを表示
;B DATA X 2
		MOVF		B_LO,W			;B_LOの内容をC_LO,D_LOへ一旦セーブ
		MOVWF		C_LO
		MOVWF		D_LO
		MOVF		B_MD,W			;B_MIDの内容をC_MID,D_MDへ
		MOVWF		C_MD
		MOVWF		D_MD
		MOVF		B_HI,W			;B_HIの内容をC_HI,D_HIへ
		MOVWF		C_HI
		MOVWF		D_HI

		BCF		STATUS,C
		RLF			C_LO,F
		RLF			C_MD,F
		RLF			C_HI,F
		BTFSC		STATUS,C
		BSF			C_TOP,0			;CARYをC_TOPにSETする

;B DATA X 3=C DATA(BX2) + D DATA=C DATA
		
		CALL		T_ADD

;C DATA+10.7(D DATA)=C DATA
		MOVLW		0x00			;
		MOVWF		D_TOP		;
		
		MOVLW		0xA3  		;SET 10,700,420Hz=A34684 TO DATA_D
		MOVWF		D_HI		;
		
		MOVLW		0x46			;
		MOVWF		D_MD		;
	
		MOVLW		0x84			;
		MOVWF		D_LO		;
		
		CALL		T_ADD
		RETURN
	
;********* バイナリ−をBCDデータ−に変換*******************

DATCNV							;4バイトバイナリ−をＢＣＤ変換

		BCF		STATUS,C
		MOVLW		020H			;Shift bit Counter
		MOVWF		SHIFT			;Shift 32回
		CLRF		DIGIT12			
		CLRF		DIGIT34	
		CLRF		DIGIT56
		CLRF		DIGIT78
CNV_LOOP
		RLF			C_LO,F
		RLF			C_MD,F
		RLF			C_HI,F
		RLF			C_TOP,F
		 
		RLF			DIGIT12,F
		RLF			DIGIT34,F
		RLF			DIGIT56,F
		RLF			DIGIT78,F
		DECFSZ		SHIFT,F
		GOTO		ADJUST
		RETURN
ADJUST
		MOVF		DIGIT12,W
		CALL		ADJBCD
		MOVWF		DIGIT12
		MOVF		DIGIT34,W
		CALL		ADJBCD
		MOVWF		DIGIT34
		MOVF		DIGIT56,W
		CALL		ADJBCD
		MOVWF		DIGIT56
		MOVF		DIGIT78,W
		CALL		ADJBCD
		MOVWF		DIGIT78
		GOTO		CNV_LOOP
ADJBCD							
		MOVWF		WORK1
		MOVLW		3
		ADDWF		WORK1,W
		MOVWF		TEMP1
		BTFSC		TEMP1,3
		MOVWF		WORK1

		MOVLW		030H
		ADDWF		WORK1,W
		MOVWF		TEMP1
		BTFSC		TEMP1,7
		MOVWF		WORK1
		MOVF		WORK1,W
		RETURN
;***********表示処理ルーチン*************************
LED_DISP
      
		BSF		STATUS,RP0	;Select bank1
        	MOVLW   	b'00000000'      	;PortB RB0-7 OUTPUT, 
        	MOVWF  	TRISB 
		bcf			STATUS,RP0		;select bank0            
		movlw		b'11110000'
		movwf		PORTB
  

;100Hz_LED1
		MOVF		DIGIT34,W		;0.1k 1k桁取り出し
		CALL		DISP1
		ADDLW		B'10000000'		;RB7=1　74244禁止 RB6-4=0 RB0-3 DATA OUT  
		MOVWF		PORTB
		nop
		ADDLW		B'01110000'		;RB7=1　74244禁止 RB6-4=1  LED1ラッチ
		MOVWF		PORTB	
		nop
;1kHz_LED2
		CALL		DISP2
		ADDLW		B'10010000'		;RB7=1 RB4=1 LED2 LATCH
		MOVWF		PORTB
		nop
		ADDLW		B'01100000'		;上位4bit FにしてラッチをH		
		MOVWF		PORTB
		nop
;10kHz_LED3
		MOVF		DIGIT56,W		;10k 100k桁取り出し
		CALL		DISP1
		ADDLW		B'10100000'		;RB7=1 74244禁止　RB5=1 LED3 LATCH
		MOVWF		PORTB
		nop
		NOP
		ADDLW		B'01010000'		;上位4bit FにしてラッチをH
		MOVWF		PORTB
		nop
;100kHz_LED4
		CALL		DISP2
		ADDLW		B'10110000'		;RB7=1 74244禁止 RB4,5=1 LED4 LATCH
		MOVWF	PORTB
		NOP
		ADDLW		B'01000000'		;上位4bit FにしてラッチをH
		MOVWF	PORTB
		nop	
;1MHz_LED5
		MOVF		DIGIT78,W		;1M,10MHz桁取り出し
		CALL		DISP1
		ADDLW		B'11000000'		;RB7=1 74244禁止 RB6=1 LED5 LATCH		
		MOVWF	PORTB
		nop
		NOP
		ADDLW		B'00110000'		;上位4bit FにしてラッチをH		
		MOVWF	PORTB
		nop	
;10MHz_LED6		
		CALL		DISP2
		ADDLW		B'11010000'		;RB7=1 74244禁止 RB4,6=1 LED6 LATCH
		MOVWF	PORTB
		nop
		NOP
		ADDLW		B'00100000'		;上位4bit FにしてラッチをH
		MOVWF	PORTB
		nop	
		
		RETURN
				
DISP1
		MOVWF	DATA_SAVE		;DATA一時保管
		ANDLW		0FH				;下位取り出し
		RETURN
DISP2
		MOVF		DATA_SAVE,W	;下位データ−取り出し
		SWAPF		DATA_SAVE,W	;上位下位入れ替え
		ANDLW		0FH				;上位取り出し
		RETURN

;******** ADDITION*********************************
;  C(32 BITS) +B(32 BITS)= C(32 BITS) 
;	1.LOAD 1ST OPERAND IN C_LO,C_MD,C_HI,C_TOP
;	2.LOAD 2ND OPERAND IN D_LO,D_MD,D_HI,D_TOP
;	3.CALL T_ADD
;	4.THE RESULT IS IN C_LO,C_MD,C_HI,D_TOP
;
;******** SUBTRACTION*****************************
;  C(32 BITS) -B(32 BITS)= C(32 BITS) 
;	1.LOAD 1ST OPERAND IN C_LO,C_MD,C_HI,C_TOP
;	2.LOAD 2ND OPERAND IN D_LO,D_MD,D_HI,D_TOP
;	3.CALL T_SUB
;	4.THE RESULT IS IN C_LO,C_MD,C_HI,C_TOP


T_SUB

		CALL		COM32		;補数計算後、加算することにより減算する
		CALL		T_ADD
		CALL		COM32
		BCF		STATUS,C
		BTFSC		CTEMP,0
		BSF			STATUS,C
		RETLW		0

T_ADD
		BCF		CTEMP,0
		MOVF		D_LO,W
		ADDWF		C_LO,F
		MOVLW		01H
		BTFSC		STATUS,C
		ADDWF		C_MD,F
		BTFSC		STATUS,C
		ADDWF		C_HI,F
		BTFSC		STATUS,C
		ADDWF		C_TOP,F
		BTFSC		STATUS,C
		BSF			CTEMP,0
		MOVF		D_MD,W
		ADDWF		C_MD,F
		MOVLW		01H
		BTFSC		STATUS,C
		ADDWF		C_HI,F
		BTFSC		STATUS,C
		ADDWF		C_TOP,F
		BTFSC		STATUS,C
		BSF			CTEMP,0

		MOVF		D_HI,W
		ADDWF		C_HI,F
		MOVLW		01H
		BTFSC		STATUS,C
		ADDWF		C_TOP,F
		BTFSC		STATUS,C
		BSF			CTEMP,0

		MOVF		D_TOP,W
		ADDWF		C_TOP,F
		BTFSC		STATUS,C
		BSF			CTEMP,0

		BTFSC		CTEMP,0
		BSF			STATUS,C
		RETLW		0

COM32
		COMF		D_LO,F
  		COMF		D_MD,F
		COMF		D_HI,F
		COMF		D_TOP,F
		MOVLW		01H
		ADDWF		D_LO,F
		BTFSC		STATUS,C
		ADDWF		D_MD,F
		BTFSC		STATUS,C
		ADDWF		D_HI,F
		BTFSC		STATUS,C
		ADDWF		D_TOP,F
		retlw		0
;++++++ TRANSMIT SERIAL DATA TO DDS ++++++++++
;  RA2:DCK(CLOCK)
;  RA3:DDT(DATA)
;  RA4:DST(STROBE)
;コマンド＝C　
TXD				;
				;ADDRESS SET
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1
				;COMMAND=C:WRT TO MEM /OUT TO DDS
		CALL		BIT0		;LSB
		CALL		BIT0	
		CALL		BIT1	
		CALL		BIT1		;MSB
				;8x3=24BITS FREQ.DATA
		MOVF		B_LO,W
		CALL		TX_BYTE		
		MOVF		B_MD,W
		CALL		TX_BYTE		
		MOVF		B_HI,W
		CALL		TX_BYTE	
				;2BITS DATA=00
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0		;STROBE=0

		RETURN


RIT_TX								;1/15 debug
				;ADDRESS SET
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1
				;COMMAND=C:WRT TO MEM /OUT TO DDS
		CALL		BIT0		;LSB
		CALL		BIT0	
		CALL		BIT1	
		CALL		BIT1		;MSB
				;8x3=24BITS FREQ.DATA
		MOVF		FTX_LO,W
		CALL		TX_BYTE		
		MOVF		FTX_MD,W
		CALL		TX_BYTE		
		MOVF		FTX_HI,W
		CALL		TX_BYTE	
				;2BITS DATA=00
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0		;STROBE=0

		RETURN


BIT1	
		BCF		PORTA,2		;CLK=0
		BSF			PORTA,3		;DATA=1
		CALL		WAIT_CLK_REV
		RETURN
BIT0	
		BCF		PORTA,2		;CLK=0
		BCF		PORTA,3		;DATA=0
		CALL		WAIT_CLK_REV
		RETURN

STROBE_1
		BSF			PORTA,4		;NORMAL STROBE=1 
		RETURN
STROBE_0
		BCF		PORTA,4		;RESET STOROBE=0
		CALL 		TIME10			;WAIT 10uS
		BSF			PORTA,4		;STROBE=1(NORMAL)
		RETURN

;***************************************
;* SENDING 1BYTE DATA IN W-REG TO DDS 
;***************************************
TX_BYTE
		MOVWF		TEMP		;save temporaly
		MOVLW		8H			;8bit counter
		MOVWF		DAT_CNT
TX_LP
		RRF			TEMP,F		;Bit shift
		BTFSS		STATUS,C	;0,1 check
		GOTO		TX_0
		GOTO		TX_1
TX_0	
		BCF		PORTA,2		;CLK=0
		BCF		PORTA,3		;0 send
		GOTO		TX_NEXT
TX_1	
		BCF		PORTA,2		;CLK=0
		BSF			PORTA,3		;1 send
TX_NEXT		
		CALL		WAIT_CLK_REV
		DECFSZ		DAT_CNT,F	;8bits end test
		GOTO		TX_LP		;Not end loop
		RETURN

WAIT_CLK_REV
		CALL 		TIME10		;10uS WAIT

		BSF			PORTA,2		;CLK REVERSE
		CALL		TIME10		;10uS WAIT
		RETURN
;---------------------------------------------------------------------
VFO_OFF				;コマンド＝０　　出力をＯＦＦ
				;ADDRESS SET
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1
				;COMMAND=0:DDS OUTPUT OFF
		CALL		BIT0		;LSB
		CALL		BIT0	
		CALL		BIT0	
		CALL		BIT0		;MSB
				;8x3=24BITS FREQ.DATA  以下はダミーデータ
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE	
				;2BITS DATA=00
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0	;STROBE=0
;FLG SET
		BSF			ONOFF_FLG,0	;OFF FLG SET
		BCF		ONOFF_FLG,1	;ON FLG RESET

		RETURN
;---------------------------------------------------------------------
VFO_SEL1			;コマンド＝８　　ＭＥＭ１を出力とする設定
				;ADDRESS SET
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1
				;COMMAND=0:DDS OUTPUT OFF
		CALL		BIT0		;LSB
		CALL		BIT0	
		CALL		BIT0	
		CALL		BIT1		;MSB
				;8x3=24BITS FREQ.DATA  以下はダミーデータ
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE	
				;2BITS DATA=00
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0	;STROBE=0

VFO_ON				;コマンド＝１　　ＤＤＳ出力　ＯＮ
				;ADDRESS SET
		CALL		STROBE_1	;STROBE=1 (NORMAL STB=1)
		CALL		BIT1		;CS0=1
		CALL		BIT1		;CS1=1
		CALL		BIT1		;CS2=1
				;COMMAND=0:DDS OUTPUT OFF
		CALL		BIT1		;LSB
		CALL		BIT0	
		CALL		BIT0	
		CALL		BIT0		;MSB
				;8x3=24BITS FREQ.DATA  以下はダミーデータ
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE		
		MOVLW		0
		CALL		TX_BYTE	
				;2BITS DATA=00
		CALL		BIT0	
		CALL		BIT0	
		CALL		STROBE_0	;STROBE=0
;FLG SET
		BSF		ONOFF_FLG,1	;ON FLG SET
		BCF		ONOFF_FLG,0	;OFF FLG RESET

		CALL		SEND_DAT		;DDSへFREQ DATA

		RETURN
;--------------------------------------------------------------------------------
;*********************************
;  Timer Routine
;	TIME10  :10usec
;	CLOCK:57usec
;*********************************
CLOCK  
	  	MOVLW		5H
		MOVWF		CNT1		;2
TIM_LP1
		CALL		TIME10		;2+(25+4)x5+1=148
		DECFSZ		CNT1,F
		GOTO		TIM_LP1
		RETURN				;148+1=149x0.4usec=59.6usec
CLOCK1  
		MOVLW		9H
		MOVWF		CNT1		;2
TIM_LP4 
		CALL		TIME10		;2+(25+4)x5+1=148
		DECFSZ		CNT1,F
		GOTO		TIM_LP4
		RETURN				;148+1=149x0.4usec=59.6usec
TIME10  
		MOVLW		5H		;+1
		MOVWF		CNT2		;1+1=2
TIM_LP2
		DECFSZ		CNT2,F		;2+4x5+1=23
		GOTO		TIM_LP2		
		NOP				;23+1=24
		RETURN				;24+1=25x0.4usec=10usec
TIME5M  
		MOVLW		2EH
		MOVWF		CNT3

TIM_LP3
           CALL		CLOCK1
		DECFSZ		CNT3,F
		GOTO		TIM_LP3
		RETURN
TIME50     
          CALL     TIME10
          CALL     TIME10
          CALL     TIME10
          CALL     TIME10
          CALL     TIME10
          RETURN
TIME1M
		MOVLW		8H
		MOVWF		CNT4
TIM_LP42
		CALL		CLOCK
		DECFSZ		CNT4,F
		GOTO		TIM_LP42
		RETURN


 PWR_OFF
		nop
		goto		PWR_OFF
               
		END